int baseHueB = 200;
int baseHueL = 30;
int baseHueSpace = 330;

boolean debug = false;

String[] lines;
String[] pieces;
String[] paths;
String[] steps;
float[][] odorField;

float maxOdor = -1;
float minOdor = 999;

String[] labels = {"A","B","C","D","E","F","G","H","J","I"};

int fieldWidth;
int fieldHeight;

int margin = 80;
int drawPathCount = 10;
PFont f;

int maxStep = -1;
int stepThreshold = -1;
int lastStepThreshold = -2;
boolean highlightStepbar = false;

LarvaPath[] larvaPaths;
Step maxOdorStep;




public void setup()
{
  frameRate(20);
  lines = loadStrings("odorFieldSimple.tsv");
  String line = lines[0];
  pieces = split(line,",");
  
  fieldWidth = int(pieces[1]);
  fieldHeight = int(pieces[0]);
  
  //size(1024,768);
  size(fieldWidth + 2 * margin,fieldHeight + 2 * margin);
  background(0);
  smooth();
  paths = loadStrings("paths.csv");

  odorField = new float[fieldHeight][10];

  minOdor = float(pieces[2]);
  maxOdor = float(pieces[3]);

	maxOdorStep = new Step(float(pieces[5]),float(pieces[4]));

  ellipseMode(CENTER);
  rectMode(CENTER);

  f = loadFont("Helvetica-10.vlw");

  textMode(MODEL);
  textAlign(CENTER);
  textFont(f);

  InitializeField();
  InitializePaths();

}

public void draw()
{
  drawSpace();
  drawStepBar();
  drawPaths();
}

public void InitializeField()
{
  String[] fieldData = lines;

  for (int i = 1;i<fieldData.length;i++)
  {
    String[] s = split(fieldData[i],TAB);
    for (int index = 0;index<s.length - 2;index++)
    {
      odorField[i - 1][index] = float(s[index + 1]);
    }
  }
}

public void InitializePaths()
{
  larvaPaths = new LarvaPath[paths.length];

  for (int i = 0;i<paths.length;i++)
  {
    steps = split(paths[i],",");
    String type = steps[0];
    int number = int(steps[1]);
    int stepCountCheck = int(steps[2]);

    if (stepCountCheck > maxStep)
    {
      maxStep = stepCountCheck;
    }

    if (steps.length != stepCountCheck + 3)
    {
      println("path error: line " + number);
      continue;//error exit
    }
    else
    {
      larvaPaths[i] = new LarvaPath(stepCountCheck,type.equals("B") ? 'B' : 'L',number);
      //println("Path #"+i+": " + stepCountCheck);
      for (int k = 0;k < stepCountCheck;k++)
      {
        String[] cord = split(steps[k + 3]," ");
        larvaPaths[i].AppendStep(float(cord[0]),float(cord[1]));
      }
    }
  }
}

void drawSpace()
{
  background(0);
  colorMode(HSB,360,100,100,100);
  rectMode(CORNER);
  
  for (int i = 0;i<fieldHeight;i++)
  {
    for (int j = 1;j<10;j++)
    {
      float pos_2 = odorField[i][j];
      float pos_1 = odorField[i][j - 1];
      
      int g = int(map(j,1,9,0,100));
      
      if (pos_2 == -1 && pos_1 == 0)
      {
        continue;
      }
      
      if (pos_2 == -1 && pos_1 != -1)
      {
        pos_2 = fieldWidth;
      }
      
      if (pos_1 != -1 && pos_2 != -1)
      {
        fill(baseHueSpace,100,g,100);
        noStroke();
        rect(TX(pos_1) + 1, TY(i) , int(TX(pos_2) - TX(pos_1)) + 1, 1);
      }
      
    }
    //println();
  }
}

void drawPaths()
{
  //if (lastStepThreshold == stepThreshold)
  //  return;
	long ts = millis();
  for (int i = 0;i<larvaPaths.length;i++)
  {
    larvaPaths[i].Draw(stepThreshold);
  }
  lastStepThreshold = stepThreshold;
  ts = millis() - ts;
	//println("path drawn in " + ts + " milliseconds");
}

void drawStepBar()
{
  colorMode(RGB,255,255,255,100);
  rectMode(CENTER);
  fill(0);
  noStroke();
  rect(width/2,margin/2,width,margin);

  if (highlightStepbar)
  {
    fill(200);
  }
  else
  {
    fill(0);
  }
  stroke(255);
  strokeWeight(1.0);
  rect(width/2, 30, 200, 4);

  int step = stepThreshold;
  if (step == -1)
  {
    step = maxStep;
  }

  noStroke();
  fill(255,70);

  rect(width/2 - 100 + map(step,1,maxStep,0,199), 30, 4, 12);

  f = loadFont("Helvetica-12.vlw");
  textAlign(CENTER);
  textFont(f);
  text("STEP 1", width/2 - 130, 35);
  text(maxStep, width/2 + 130, 35);
  text(step, width/2 - 100 + map(step,1,maxStep,0,199), margin - 20);
}


void mouseMoved()
{
  
}

void mouseDragged()
{
	if ((mouseX >= width/2 - 100) && (mouseX < width/2 + 100) && (mouseY >= 20) && (mouseY < 40))
  {
    highlightStepbar = true;
  }
  else
  {
    highlightStepbar = false;
  }

	if ((mouseX >= width/2 - 100) && (mouseX < width/2 + 100) && (mouseY >= 25) && (mouseY < 35))
  {
    stepThreshold = int(map(mouseX,width/2 - 100, width/2 + 99, 1, maxStep));
  }
}

void mouseReleased()
{
  if ((mouseX >= width/2 - 100) && (mouseX < width/2 + 100) && (mouseY >= 25) && (mouseY < 35))
  {
    stepThreshold = int(map(mouseX,width/2 - 100, width/2 + 99, 1, maxStep));
  }
	highlightStepbar = false;
}

void keyPressed()
{
  if (key == '+' || key == '=')
  {
    lastStepThreshold = stepThreshold;
    
    if (stepThreshold < maxStep)
    {
      stepThreshold++;
    }
  }

  if (key == '-')
  {
    lastStepThreshold = stepThreshold;
    if (stepThreshold == -1)
    {
      stepThreshold = maxStep;
    }
    if (stepThreshold > 1)
    {
      stepThreshold--;
    }
  }

	if (key >= '0' && key <= '9')
	{
		drawPathCount = int(key - '0');
		if (drawPathCount == 0)
			drawPathCount = 10;
		println("draw path count: " + drawPathCount);
	}
	
	if (key == 'd')
	{
		debug = !debug;
	}
}

public float TX(float x)
{
  return map(x,0,fieldWidth,0,width - 2 * margin) + margin;
}

public float TY(float y)
{
  return map(y,0,fieldHeight,0,height - 2 * margin) + margin;
}